Ein Gehäuse für den Commander X16

Nun da ich den Computer hier habe, muss natürlich ein schickes Gehäuse her. Meine Wahl viel auf das UNYKAch UK3002 MATX Slim Case. Ein schlichtes Gehäuse ohne viel Klim-Bim.

Der Commander X16 war schnell eingebaut. Und da ein PicoPSU – Netzteil verbaut wurde, ist unten im Gehäuse noch jede menge Platz…

… am besten für ein Steckbrett! 😀 Also gleich mal ein Display geschnappt und ein kleines BASIC Programm zu ansteuern geschrieben!

5 REM ADRESSEN DES VIA
10 OA = $9F11
20 DA = $9F13
25 REM PINS ALS AUSGANG SETZEN
30 POKE DA, $3F
35 REM 4 BIT MODUS EINSTELLEN
40 N = 3
50 GOSUB 3000
60 FOR D = 1 TO 10 : NEXT D
70 GOSUB 3000
90 GOSUB 3000
100 REM DISPLAY EINSTELLEN
110 N = 2
120 GOSUB 3000
130 C = $28
140 GOSUB 1000
150 C = $0C
160 GOSUB 1000
170 C = $06
180 GOSUB 1000
190 C = $01
200 GOSUB 1000
201 C = $80
202 GOSUB 1000
205 REM BEGINN DER TEXTAUSGABE
210 M$ = "HALLO ELECTRIX!"
220 FOR I = 1 TO LEN(M$)
230 C = ASC(MID$(M$, I, 1))
240 GOSUB 2000
250 NEXT I
255 REM ZWEITE ZEILE
260 C = $C0
270 GOSUB 1000
275 REM TEXTAUSGABE
280 M$ = "ICH BIN DER CX16"
290 FOR I = 1 TO LEN(M$)
300 C = ASC(MID$(M$, I, 1))
310 GOSUB 2000
320 NEXT I
330 END
340 REM ENDE
999 REM COMMAND SENDEN
1000 V = PEEK(OA) AND $EF
1010 POKE OA, V
1020 N = (C AND $F0) / 16
1030 GOSUB 3000
1040 N = C AND $0F
1050 GOSUB 3000
1100 RETURN
1999 REM DATEN SENDEN
2000 V = PEEK(OA) OR $10
2010 POKE OA, V
2020 N = (C AND $F0) / 16
2030 GOSUB 3000
2040 N = C AND $0F
2050 GOSUB 3000
2060 RETURN
2999 REM NIBBLE SENDEN
3000 V = PEEK(OA)
3010 V = (V AND $F0) OR (N AND $0F)
3020 POKE OA, V
3030 POKE OA, V OR $20
3050 POKE OA, V
3100 RETURN

Und das ist ein kleines BASIC Programm zum Ansteuern eines LCDs! #bonus 😀